EeaFigure and data

PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX rdf-syntax: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX s: <http://www.eea.europa.eu/portal_types/Specification#>
PREFIX a: <http://www.eea.europa.eu/portal_types/Assessment#>
PREFIX ap: <http://www.eea.europa.eu/portal_types/AssessmentPart#>
PREFIX fig: <http://www.eea.europa.eu/portal_types/EEAFigure#>
PREFIX data: <http://www.eea.europa.eu/portal_types/Data#>
PREFIX ed: <http://www.eea.europa.eu/portal_types/ExternalDataSpec#>
PREFIX dv: <http://www.eea.europa.eu/portal_types/DavizVisualization#>

SELECT DISTINCT
?code as ?ind_code
?s_manager_user_id as ?ind_manager
?ap_related_items as ?figure
?ap_related_items_label as ?figure_label
?ap_related_items_maptype as ?figure_type
?relatedItems as ?data
?relatedItems_title as ?data_title

IF (?data_type = data:Data, "data", "exData") as ?data_type

IF (bif:isnull(?data_owner), ?exdata_provider_url, ?data_owner) as ?data_provider 
?relatedItems_creator as ?data_creator

WHERE {
  ?s dcterms:title ?s_title .
  ?s s:codes ?code .
  ?s rdf-syntax:type ?type . FILTER (?type = s:Specification)
  OPTIONAL { ?s dcterms:isReplacedBy ?isReplacedBy . }
  OPTIONAL { ?s s:manager_user_id ?s_manager_user_id . }
  FILTER (!bound(?isReplacedBy))

  ?s dcterms:hasPart ?a .
  ?a a:id ?a_id .
  ?a rdf-syntax:type ?a_type . FILTER (?a_type = a:Assessment) 
  OPTIONAL { ?a dcterms:isReplacedBy ?a_isReplacedBy . }
  OPTIONAL { ?a dcterms:creator ?a_creator . }
  FILTER (!bound(?a_isReplacedBy))

  ?a dcterms:hasPart ?ap .
  ?ap rdf-syntax:type ?ap_type . FILTER (?ap_type = ap:AssessmentPart) 
  ?ap ap:relatedItems ?ap_related_items .
  ?ap_related_items rdf-syntax:type ?ap_related_items_type . FILTER (?ap_related_items_type = fig:EEAFigure)
  ?ap_related_items fig:figureType ?ap_related_items_maptype .
  #?ap_related_items fig:figureType ?ap_related_items_maptype .  FILTER (str(?ap_related_items_maptype)  = 'map')
  ?ap_related_items rdfs:label ?ap_related_items_label .

  ?ap_related_items fig:relatedItems ?relatedItems .
  ?relatedItems rdf-syntax:type ?data_type . FILTER (?data_type in (ed:ExternalDataSpec, data:Data)) 
  ?relatedItems dcterms:title ?relatedItems_title .
  ?relatedItems dcterms:creator ?relatedItems_creator .

  OPTIONAL { ?relatedItems data:dataOwner ?data_owner } .
  OPTIONAL { ?relatedItems ed:provider_url ?exdata_provider_url } .

} 
ORDER BY ?code