kbn indicators

PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX rdf-syntax: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX Specification: <http://www.eea.europa.eu/portal_types/Specification#>
PREFIX external: <http://www.eea.europa.eu/portal_types/external#>
PREFIX Assessment: <http://www.eea.europa.eu/portal_types/Assessment#>
PREFIX AssessmentPart: <http://www.eea.europa.eu/portal_types/AssessmentPart#>
PREFIX EEAFigure: <http://www.eea.europa.eu/portal_types/EEAFigure#>
PREFIX Data: <http://www.eea.europa.eu/portal_types/Data#>
PREFIX ExternalDataSpec: <http://www.eea.europa.eu/portal_types/ExternalDataSpec#>
PREFIX DavizVisualization: <http://www.eea.europa.eu/portal_types/DavizVisualization#>
PREFIX portal_types: <http://www.eea.europa.eu/portal_types#>
PREFIX themes: <http://www.eea.europa.eu/portal_vocabularies/themes/>
PREFIX ontologies: <http://www.eea.europa.eu/ontologies.rdf#>
PREFIX states: <http://www.eea.europa.eu/portal_workflow/indicators_workflow/states/>

SELECT
  ?code as ?indicatorCode
  ?indicatorFamily
  ?specificationTitle
  ?dpsir
  ?typology
  ?managerUserId
  ?specification
  ?topicLabel
  ?assessment
  coalesce(?yearsTemporalCoverage, 0) as ?yearsTemporalCoverage
  coalesce(?minTemporalCoverage, 0) as ?minTemporalCoverage
  coalesce(?maxTemporalCoverage, 0) as ?maxTemporalCoverage
  coalesce(?spatial, 0) as ?spatial
  (bif:datediff('day',?assessmentCreated, ?assessmentIssued)+1) as ?publicationDelay
  ?assessmentCreated
  ?assessmentModified
  ?assessmentIssued
  ?assessmentExpires
  ?managementPlan
  ?managementPlanUri
  coalesce(?frequencyOfUpdates, 0) as ?frequencyOfUpdates
  ?data
  ?dataTitle
  ?dataType
  bif:either(!bound(?dataProvider), xsd:string(?data), ?dataProvider) as ?dataProvider
  ?dataIssued
  #coalesce(?reportingObligations, "None") as ?reportingObligations
  bif:either(bif:isnull(?reportingObligations), "", concat("http://rod.eionet.europa.eu/obligations/", ?reportingObligations)) as ?reportingObligationsUri
  ?priority
  {{
    SELECT DISTINCT
      ?code
      bif:left(?code, strlen(?code)-3) as ?indicatorFamily
      ?specificationTitle
      ?managerUserId
      ?specification
      ?dpsir
      ?typology
      ?topicLabel
      ?assessment
      ?yearsTemporalCoverage
      ?minTemporalCoverage
      ?maxTemporalCoverage
      count(?spatial) as ?spatial
      ?countSpatial
      ?assessmentCreated
      ?assessmentModified
      ?assessmentIssued
      ?assessmentExpires
      ?managementPlan
      iri(bif:concat('http://applications/managementplan/ProjectPlan.aspx?year=', bif:left(?managementPlan, 4 ), '&code=', bif:right(?managementPlan, 5 ))) as ?managementPlanUri
      xsd:int(bif:left(bif:right(?frequencyOfUpdates, 6), 1))   as ?frequencyOfUpdates
      ?data
      ?dataTitle
      bif:either(?dataType = Data:Data, 'Data', 'External data') as ?dataType
      bif:either(bif:isnull(?dataOwner), ?exdataProviderUrl, ?dataOwner) as ?dataProvider
      ?dataIssued
      ?reportingObligations
      bif:either(bound(?reportingObligations), 'Yes', 'No') as ?priority
    WHERE {{
      ?specification dcterms:title ?specificationTitle .
      ?specification Specification:codes ?code .
      FILTER (bif:left(?code, 3) != 'CSI') .
      ?specification Specification:dpsir ?dpsir .
      ?specification Specification:typology ?typology .
      ?specification rdf-syntax:type Specification:Specification .
      ?specification Specification:frequency_of_updates ?frequencyOfUpdates .
      ?specification Specification:manager_user_id ?managerUserId .
      ?specification portal_types:topic ?topic .
      ?specification ontologies:hasWorkflowState states:published .
      ?topic rdfs:label ?topicLabel .
      OPTIONAL { ?specification dcterms:isReplacedBy ?specificationIsReplacedBy . }
      FILTER (!bound(?specificationIsReplacedBy))
      OPTIONAL { ?specification Specification:manager_user_id ?specificationManagerUserId . }
      ?assessment dcterms:isPartOf ?specification .
      {{
        SELECT
        ?assessment
        (max(xsd:integer(?temporalCoverage)) - min(xsd:integer(?temporalCoverage))+1)  as ?yearsTemporalCoverage
        min(xsd:integer(?temporalCoverage)) as ?minTemporalCoverage
        max(xsd:integer(?temporalCoverage)) as ?maxTemporalCoverage
        ?spatial
        ?assessmentCreated
        ?assessmentModified
        ?assessmentIssued
        coalesce(?assessmentExpires, "9999-12-31T00:00:00Z"^^xsd:dateTime) as ?assessmentExpires
          {{
            SELECT DISTINCT
              ?assessment
              ?temporalCoverage
              ?spatial
              ?assessmentCreated
              ?assessmentModified
              ?assessmentIssued
              ?assessmentExpires 
            WHERE {{
              ?assessment rdf-syntax:type Assessment:Assessment .
              OPTIONAL { ?assessment Assessment:temporalCoverage ?temporalCoverage } .
              OPTIONAL { ?assessment dcterms:spatial ?spatial } .
              ?assessment dcterms:created ?assessmentCreated .
              ?assessment dcterms:modified ?assessmentModified .
              ?assessment dcterms:issued ?assessmentIssued .
              OPTIONAL { ?assessment dcterms:expires ?assessmentExpires } .
            }}
          }}
      }}
      ?assessment rdf-syntax:type Assessment:Assessment .
      ?assessment ontologies:hasWorkflowState states:published .
      OPTIONAL { ?assessment Assessment:management_plan ?managementPlan } .
      OPTIONAL { ?assessment dcterms:isReplacedBy ?assessmentIsReplacedBy } .
      FILTER (!bound(?assessmentIsReplacedBy))
      ?specification  Specification:relatedItems ?data .
      OPTIONAL { ?data dcterms:title ?dataTitle }
      OPTIONAL { ?data rdf-syntax:type ?dataType }
      FILTER (?dataType in (ExternalDataSpec:ExternalDataSpec, Data:Data))
      OPTIONAL { ?data ExternalDataSpec:provider_url ?exdataProviderUrl }
      OPTIONAL { ?data Data:dataOwner ?dataOwner } .
      OPTIONAL { ?data Data:reportingObligations ?reportingObligations } .
      OPTIONAL { ?data dcterms:issued ?dataIssued } .
    }}
  }}
ORDER BY ?indicatorCode