Total final energy intensity, 2005-2017

PREFIX sdmx-measure: <http://purl.org/linked-data/sdmx/2009/measure#> 
PREFIX sdmx-dimension: <http://purl.org/linked-data/sdmx/2009/dimension#>
PREFIX sdmx-attribute: <http://purl.org/linked-data/sdmx/2009/attribute#> 
PREFIX skos: <http://www.w3.org/2004/02/skos/core#> 
PREFIX property: <http://rdfdata.eionet.europa.eu/eurostat/property#> 
PREFIX unit: <http://dd.eionet.europa.eu/vocabulary/eurostat/unit/>
PREFIX siec: <http://dd.eionet.europa.eu/vocabulary/eurostat/siec/>
PREFIX nrg_bal: <http://dd.eionet.europa.eu/vocabulary/eurostat/nrg_bal/>
PREFIX geo: <http://dd.eionet.europa.eu/vocabulary/eurostat/geo/>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX tableFile: <http://semantic.eea.europa.eu/project/indicators/gap_filling_data/GHG_GDP.tsv#>


SELECT
?ugeo

round(( bif:power( (sum(?nrg_bal_c_last)/sum(?ghg_gdp_last))/(sum(?nrg_bal_c_first)/sum(?ghg_gdp_first)) , (1.0/(2017-2005))) -1.0) * 10000.0)/ 100.0 as ?index

#sum(?nrg_bal_c_last)/sum(?ghg_gdp_last)
#sum(?nrg_bal_c_first)/sum(?ghg_gdp_first)

#sum(?nrg_bal_c_first) as ?nrg_bal_c_first
#sum(?nrg_bal_c_last) as ?nrg_bal_c_last
#sum(?ghg_gdp_first) as ?ghg_gdp_first
#sum(?ghg_gdp_last) as ?ghg_gdp_last 

WHERE {
    {
    GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nrg_bal_c.rdf.gz> {
    {
        _:nrg_bal_c sdmx-attribute:unitMeasure unit:KTOE .
        _:nrg_bal_c sdmx-dimension:refArea ?geo .
        _:nrg_bal_c property:nrg_bal nrg_bal:FC_E .
        _:nrg_bal_c property:siec siec:TOTAL .
        {
          _:nrg_bal_c sdmx-dimension:timePeriod ?date .
          FILTER (year(?date) = 2005)
          _:nrg_bal_c sdmx-measure:obsValue ?nrg_bal_c_first .
        } UNION {
          _:nrg_bal_c sdmx-dimension:timePeriod ?date .
          FILTER (year(?date) = 2017)
          _:nrg_bal_c sdmx-measure:obsValue ?nrg_bal_c_last .
        }
    }}
  } UNION {
    GRAPH <http://semantic.eea.europa.eu/project/indicators/gap_filling_data/GHG_GDP.tsv> {
     {
        _:rec tableFile:refArea ?geo .
        _:rec tableFile:ValueDescription 'Estimate of GDP in Euro at 2010 prices (Mrd)' .
        {
          _:rec tableFile:Year ?date .
          FILTER (year(?date) = 2005)
          _:rec tableFile:obsValue ?ghg_gdp_first .
        } UNION {
          _:rec tableFile:Year ?date .
          FILTER (year(?date) = 2017)
          _:rec tableFile:obsValue ?ghg_gdp_last .
        }
    }}
  }
   ?geo rdfs:label ?ugeo .
}
GROUP BY ?geo ?ugeo
ORDER BY ?index