Last version of a indicator specification, last version of related data, both connected with a reporting obligation of a priority data flow

PREFIX dcterms: <http://purl.org/dc/terms/>
PREFIX Specification: <http://www.eea.europa.eu/portal_types/Specification#>
PREFIX Data: <http://www.eea.europa.eu/portal_types/Data#>
PREFIX rod: <http://rod.eionet.europa.eu/schema.rdf#>
PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

SELECT
?codes
?Specification
sql:GROUP_CONCAT(?reportingObligations ,', ') as ?reportingObligations 
?dataLastVersion as ?data
?data_label
{{
	SELECT 
	sql:GROUP_CONCAT(?codes,', ') as ?codes
	?Specification
	?reportingObligations 
	?dataLastVersion
        ?data_label
	{{
		SELECT DISTINCT
		?codes
		?Specification
		?reportingObligations 
		?dataLastVersion
                ?data_label
		WHERE {
		  ?Specification a Specification:Specification .
		  ?Specification Specification:codes ?codes .
		  ?Specification Specification:relatedItems ?Data .
		  OPTIONAL { ?Specification dcterms:isReplacedBy ?specificationIsReplacedBy } .
		  FILTER (!bound(?specificationIsReplacedBy )) .
		  
		  ?Data a Data:Data .
		  OPTIONAL { ?Data dcterms:isReplacedBy ?dataLastVersion} .

		  FILTER NOT EXISTS { ?dataLastVersion dcterms:isReplacedBy ?dataLastVersionIsReplacedBy }

		  ?dataLastVersion Data:reportingObligations ?reportingObligations .
                  ?dataLastVersion rdfs:label ?data_label .

		  ?Obligation a rod:Obligation .
		  ?Obligation rod:isEEAPrimary 1 .
		  ?Obligation skos:notation ?reportingObligations  .
		}
	}}
	GROUP BY ?Specification ?dataLastVersion ?reportingObligations ?data_label
}}
GROUP BY ?codes ?Specification ?dataLastVersion ?data_label
ORDER BY ?codes