Trends in EU-28 environmental protection expenditure (EPE) by organisation type, in absolute value (2010 fixed prices) and share of GDP

PREFIX sdmx-measure: <http://purl.org/linked-data/sdmx/2009/measure#> 
PREFIX sdmx-dimension: <http://purl.org/linked-data/sdmx/2009/dimension#> 
PREFIX sdmx-attribute: <http://purl.org/linked-data/sdmx/2009/attribute#> 
PREFIX property: <http://rdfdata.eionet.europa.eu/eurostat/property#> 
PREFIX unit: <http://dd.eionet.europa.eu/vocabulary/eurostat/unit/>
PREFIX geo: <http://dd.eionet.europa.eu/vocabulary/eurostat/geo/>
PREFIX ceparema: <http://dd.eionet.europa.eu/vocabulary/eurostat/ceparema/>
PREFIX env_econ: <http://dd.eionet.europa.eu/vocabulary/eurostat/env_econ/>
PREFIX nace_r2: <http://dd.eionet.europa.eu/vocabulary/eurostat/nace_r2/>
PREFIX na_item: <http://dd.eionet.europa.eu/vocabulary/eurostat/na_item/>

SELECT
?date
round (?pepsgg/?PD10_EUR*10000000)/100.0 as ?government
round (?pepssp/?PD10_EUR*10000000)/100.0 as ?specializedServiceProvider
round (?pepsnsp/?PD10_EUR*10000000)/100.0 as ?industry
round(   ((((?pepsgg+?pepssp+?pepsnsp)/?PD10_EUR*10000000 )/?CLV10_MEUR))*100.0)/100.0 as ?gdpShare
{

  SELECT DISTINCT
    year(?date) as ?date
    sum(?pepsgg) as ?pepsgg
    (sum(?pepssp_EPS_P11)+sum(?pepssp_EPS_P51G_NP)-sum(?pepssp_EPS_P2_EPS_SP)) as ?pepssp
    sum(?pepsnsp) as ?pepsnsp
    sum(xsd:double(?PD10_EUR))*1000 as ?PD10_EUR
    sum(?CLV10_MEUR) as ?CLV10_MEUR
  WHERE {
   {
    GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/env_ac_pepsgg.rdf.gz>
      {
        _:env_ac_pepsgg sdmx-dimension:timePeriod ?date .
        _:env_ac_pepsgg property:ceparema ceparema:TOT_CEPA .
        _:env_ac_pepsgg sdmx-dimension:refArea geo:EU28 .
        _:env_ac_pepsgg sdmx-attribute:unitMeasure unit:MIO_EUR .
        _:env_ac_pepsgg property:env_econ ?env_econ .
        FILTER (?env_econ in (env_econ:EPS_P1, env_econ:EPS_P51G_NP))
        _:env_ac_pepsgg sdmx-measure:obsValue ?pepsgg .
      } 
   } UNION {
    GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/env_ac_pepssp.rdf.gz>
      {
        _:env_ac_pepssp sdmx-dimension:timePeriod ?date .
        _:env_ac_pepssp property:ceparema ceparema:TOT_CEPA .
        _:env_ac_pepssp sdmx-dimension:refArea geo:EU28 .
        _:env_ac_pepssp sdmx-attribute:unitMeasure unit:MIO_EUR .
        {
          _:env_ac_pepssp property:env_econ env_econ:EPS_P11 .
          _:env_ac_pepssp sdmx-measure:obsValue ?pepssp_EPS_P11 .
        } UNION {
          _:env_ac_pepssp property:env_econ env_econ:EPS_P2_EPS_SP .
          _:env_ac_pepssp sdmx-measure:obsValue ?pepssp_EPS_P2_EPS_SP .
        } UNION {
          _:env_ac_pepssp property:env_econ env_econ:EPS_P51G_NP .
          _:env_ac_pepssp sdmx-measure:obsValue ?pepssp_EPS_P51G_NP .
        }
      }      
   } UNION {
    GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/env_ac_pepsnsp.rdf.gz>
      {
        _:env_ac_pepsnsp sdmx-dimension:timePeriod ?date .
        _:env_ac_pepsnsp property:nace_r2 nace_r2:EP_BUS .
        _:env_ac_pepsnsp property:ceparema ceparema:TOT_CEPA .
        _:env_ac_pepsnsp sdmx-dimension:refArea geo:EU28 .
        _:env_ac_pepsnsp sdmx-attribute:unitMeasure unit:MIO_EUR .
        _:env_ac_pepsnsp property:env_econ ?env_econ .
        FILTER (?env_econ in (env_econ:EPS_P1_ANC, env_econ:EPS_P51G_NP))
        _:env_ac_pepsnsp sdmx-measure:obsValue ?pepsnsp .
      
      } 
   } UNION {
    GRAPH <http://rdfdata.eionet.europa.eu/eurostat/data/nama_10_gdp.rdf.gz>
      {
        _:nama_10_gdp sdmx-dimension:timePeriod ?date . 
        _:nama_10_gdp property:na_item na_item:B1GQ . 
        _:nama_10_gdp sdmx-dimension:refArea geo:EU28 .
        _:nama_10_gdp sdmx-attribute:unitMeasure ?unit .
        {
          _:nama_10_gdp sdmx-attribute:unitMeasure unit:PD10_EUR .
          _:nama_10_gdp sdmx-measure:obsValue ?PD10_EUR .
        } UNION {
          _:nama_10_gdp sdmx-attribute:unitMeasure unit:CLV10_MEUR .
          _:nama_10_gdp sdmx-measure:obsValue ?CLV10_MEUR .
        }
      }
    }
    FILTER (year(?date) >= 2006)
  }
}